49 lines
1.6 KiB
OCaml
49 lines
1.6 KiB
OCaml
(* /terms + /privacy *)
|
|
|
|
let aux asset req _server _env =
|
|
let etag = Assets.etag asset in
|
|
let headers = Vifu.Request.headers req in
|
|
let has_matching_etag =
|
|
match Vifu.Headers.get headers "if-none-match" with
|
|
| None -> Ok false
|
|
| Some s ->
|
|
Headers_lib.If_none_match.parse s
|
|
|> Result.map (Headers_lib.If_none_match.evaluate etag)
|
|
in
|
|
match has_matching_etag with
|
|
| Error e -> Respond.bad_request ~hint:e req
|
|
| Ok true -> Respond.not_modified ()
|
|
| Ok false ->
|
|
let mime = Headers.select_mimetype headers in
|
|
let lang = Headers.select_language headers in
|
|
let compression = Headers.select_encoding headers in
|
|
let data = Assets.get_content ~mime ~lang asset in
|
|
(* -- *)
|
|
let open Vifu.Response in
|
|
let open Syntax in
|
|
let* () = with_string ?compression req data in
|
|
let* () =
|
|
let etag_field_value = Headers_lib.Etag.to_field_string etag in
|
|
add ~field:"etag" etag_field_value
|
|
in
|
|
let* () =
|
|
add ~field:"taler-terms-version"
|
|
Assets.Assets_config.terms_legal_version
|
|
in
|
|
let* () =
|
|
add ~field:"avail-languages" Headers.avail_languages_header_value
|
|
in
|
|
let* () =
|
|
let content_type = Fmt.str "%a" Assets.Mimetype.pp mime in
|
|
add ~field:"content-type" content_type
|
|
in
|
|
let* () = add ~field:"content-language" lang in
|
|
respond `OK
|
|
|
|
let terms req _server _env =
|
|
Logs.info (fun m -> m "GET /terms");
|
|
aux Assets.Terms req _server _env
|
|
|
|
let privacy req _server _env =
|
|
Logs.info (fun m -> m "GET /privacy");
|
|
aux Assets.Privacy req _server _env
|