open Syntax

let read_file fname = Bos.OS.File.read (Fpath.v fname) |> unwrap_err_msg

let write_file fname content =
  Bos.OS.File.write (Fpath.v fname) content |> unwrap_err_msg

let base_url = Uri.of_string "http://localhost:3434/"

let management_keys_url =
  Uri.with_path base_url "/management/keys/" |> Uri.to_string

let download ~output =
  let open Bos in
  let uri = management_keys_url in
  OS.Cmd.run Cmd.(v "curl" % "-s" % "-o" % output % "-X" % "GET" % uri)
  |> unwrap_err_msg

let upload ~input =
  let open Bos in
  let uri = management_keys_url in
  OS.Cmd.run
    Cmd.(
      v "curl"
      % "-i"
      % "-X"
      % "POST"
      % "-H"
      % "Content-Type: application/json"
      % "--data"
      % ("@" ^ input)
      % uri)
  |> unwrap_err_msg

let setup ~output =
  let () = Mirage_crypto_rng_unix.use_default () in
  let priv, pub = Mirage_crypto_ec.Ed25519.generate () in
  Fmt.pr "generated master public key:@\n%s@."
    (Mirage_crypto_ec.Ed25519.pub_to_octets pub |> B32.encode);
  let priv_data = Mirage_crypto_ec.Ed25519.priv_to_octets priv in
  write_file output priv_data

let sign ~master_key ~input ~output =
  let open Crypto in
  let* input = read_file input in
  let* master_key = read_file master_key in
  let master_key = EddsaPrivateKey.of_octets master_key in
  let* future_keys_response = Api.decode Api.FutureKeysResponse.jsont input in
  let* () = Offline_sig.verify_future_keys_response future_keys_response in
  let master_signatures =
    Offline_sig.make_master_signatures ~master_key future_keys_response
  in
  let* s = Api.encode Api.MasterSignatures.jsont master_signatures in
  let* () = write_file output s in
  Ok ()