(* parse config file
   https://docs.taler.net/manpages/taler-exchange.conf.5.html

   do not support "$"-path expansion*)

open Angstrom

type item = {
  key: string;
  value: string;
}

type section = {
  header: string;
  items: item list;
}

let fail fmt =
  let k _ppf = exit 1 in
  Fmt.kpf k Fmt.stderr ("Configuration failure: " ^^ fmt ^^ ".@.")

let is_eol = function '\n' | '\r' -> true | _ -> false
let is_whitespace = function ' ' | '\t' -> true | _ -> false
let whitespace = skip_while is_whitespace

module Parse_data = struct
  type line =
    | Blank
    | Comment of string
    | Header of string
    | Item of item

  let id =
    let ident_char = function
      | 'a' .. 'z' | 'A' .. 'Z' | '0' .. '9' | '_' | '-' -> true
      | _ -> false
    in
    take_while1 ident_char >>| String.lowercase_ascii

  let take_till_end_of_line =
    take_till is_eol >>= fun s -> return s <* end_of_line

  let blank = whitespace <* end_of_line >>| fun () -> Blank

  let comment =
    whitespace *> (char '#' <|> char '%') *> take_till_end_of_line >>| fun s ->
    Comment s

  let header = char '[' *> id <* char ']' <* end_of_line >>| fun s -> Header s

  let item_value =
    let unquoted_value =
      take_while1 (fun c -> not (is_whitespace c || is_eol c))
    in
    let quoted_value =
      char '"' *> take_till is_eol >>= fun s ->
      match String.ends_with ~suffix:"\"" s with
      | false -> fail "invalid quoted value"
      | true ->
          let value = String.sub s 0 (String.length s - 1) in
          return value
    in
    quoted_value <|> unquoted_value

  let item =
    lift2
      (fun key value -> Item { key; value })
      id
      (whitespace *> char '=' *> whitespace *> item_value)
    <* end_of_line

  let config = many (choice [ blank; comment; header; item ]) <* end_of_input

  let fold_sections l =
    let rec loop section_l item_l l =
      match l with
      | [] ->
          if List.is_empty item_l then section_l
          else fail "invalid configuration structure"
      | Blank :: tl | Comment _ :: tl -> loop section_l item_l tl
      | Item item :: tl -> loop section_l (item :: item_l) tl
      | Header header :: tl ->
          let section = { header; items= item_l } in
          loop (section :: section_l) [] tl
    in
    loop [] [] (List.rev l)

  let parse s =
    match parse_string ~consume:All config s with
    | Error msg -> fail "parse error `%s`" msg
    | Ok v -> fold_sections v
end

module Pp_debug = struct
  let pp_item ppf { key; value } =
    let open Fmt in
    match String.contains value '"' || String.contains value ' ' with
    | false -> pf ppf "%s = %s" key value
    | true -> pf ppf "%s = \"%s\"" key value

  let pp_line ppf line =
    let open Fmt in
    let open Parse_data in
    match line with
    | Blank -> Fmt.nop ppf ()
    | Comment s -> pf ppf "#%s" s
    | Header s -> pf ppf "[%s]" s
    | Item item -> pf ppf "%a" pp_item item

  let _pp_lines ppf raw_line_l =
    let open Fmt in
    pf ppf "%a" (list ~sep:(any "\n") pp_line) raw_line_l

  let pp_section ppf { header; items } =
    let open Fmt in
    pf ppf "[%s]@\n%a" header (list ~sep:(any "\n") pp_item) items

  let pp_config ppf l =
    let open Fmt in
    pf ppf "%a" (list ~sep:(any "\n") pp_section) l
end
[@@ocaml.warning "-32"]

module Parse_duration = struct
  type duration_element = {
    number: int;
    dunit: [ `Year | `Week | `Day | `Hour | `Minute | `Second ];
  }

  let integer =
    take_while1 (function '0' .. '9' -> true | _ -> false) >>= fun s ->
    match int_of_string_opt s with
    | None -> fail "expected integer, got `%s`" s
    | Some i -> return i

  let duration_element =
    let number = whitespace *> integer in
    let dunit =
      whitespace *> take_while1 (fun c -> not (is_whitespace c || is_eol c))
      >>= function
      | "year" | "years" -> return `Year
      | "week" | "weeks" -> return `Week
      | "day" | "days" -> return `Day
      | "hour" | "hours" -> return `Hour
      | "minute" | "minutes" -> return `Minute
      | "second" | "seconds" | "s" -> return `Second
      | s -> fail "expected a duration unit, got `%s`" s
    in
    lift2 (fun number dunit -> { number; dunit }) number dunit

  let duration = many1 duration_element <* end_of_input

  let dunit_to_seconds u =
    let rec f = function
      | `Year -> 365 * f `Day
      | `Week -> 7 * f `Day
      | `Day -> 24 * f `Hour
      | `Hour -> 60 * f `Minute
      | `Minute -> 60 * f `Second
      | `Second -> 1
    in
    f u

  let ptime_span_of_int64 i =
    match Ptime.Span.of_float_s (Int64.to_float i) with
    | None ->
        fail "ptime_span_of_int64 error: `%Ld` is not a valid ptime span" i
    | Some ts -> ts

  let to_ptime_span t =
    let acc =
      List.fold_left
        (fun acc { number; dunit } -> acc + (number * dunit_to_seconds dunit))
        0 t
    in
    let acc = Int64.of_int acc in
    let ptime = ptime_span_of_int64 acc in
    ptime

  let parse s : duration_element list =
    match parse_string ~consume:All duration s with
    | Error msg -> fail "duration parse error `%s`" msg
    | Ok v -> v
end

let unwrap_res = function Error e -> fail "`%s`." e | Ok v -> v

let get_opt t ~section ~field =
  match List.find_opt (fun v -> v.header = section) t with
  | None -> None
  | Some v -> (
      match List.find_opt (fun item -> item.key = field) v.items with
      | None -> None
      | Some item -> Some item.value)

let get t ~section ~field =
  match get_opt t ~section ~field with
  | None -> fail "option `[%s].%s` not found" section field
  | Some v -> v

let int s =
  match int_of_string_opt s with
  | None -> fail "expected int value, got `%s`" s
  | Some v -> v

let float s =
  match float_of_string_opt s with
  | None -> fail "expected float value, got `%s`" s
  | Some v -> v

let const_value a b =
  match a = b with false -> fail "unexpected value `%s`" b | true -> a

let yes_no = function
  | "NO" -> `NO
  | "YES" -> `YES
  | s -> fail "expected `YES`/`NO` value, got `%s`" s

let uri s = Uri.of_string s
let amount s = s |> Amount.of_string |> unwrap_res
let duration s = Parse_duration.(s |> parse |> to_ptime_span)

let ed25519 s =
  s
  |> B32.decode
  |> unwrap_res
  |> Mirage_crypto_ec.Ed25519.pub_of_octets
  |> Result.map_error (fun e -> Fmt.str "%a" Mirage_crypto_ec.pp_error e)
  |> unwrap_res

module Parse_alt_unit_names = struct
  let rm_brackets s =
    let s = String.trim s in
    match
      String.starts_with ~prefix:"{" s && String.ends_with ~suffix:"}" s
    with
    | false -> fail "expected json, got `%s`" s
    | true ->
        let s = String.sub s 1 (String.length s - 2) in
        s

  let rm_quotes s =
    let s = String.trim s in
    match
      String.starts_with ~prefix:"\"" s && String.ends_with ~suffix:"\"" s
    with
    | false -> fail "expected quoted string, got `%s`" s
    | true ->
        let s = String.sub s 1 (String.length s - 2) in
        s

  let parse s =
    let s = rm_brackets s in
    String.split_on_char ',' s
    |> List.map (String.split_on_char ':')
    |> List.map (function
      | [ k; v ] -> (k, v)
      | _ -> fail "invalid json key-value map")
    |> List.map (fun (k, v) ->
        let k = rm_quotes k in
        let v = rm_quotes v in
        let k =
          match int_of_string_opt k with
          | None ->
              fail "invalid json key-value map, expected integer key, got `%s`"
                k
          | Some k -> k
        in
        (k, v))
end