open Api
open Devices

let mk_future_denom ~key
    ({
       pub;
       priv= _;
       section_name;
       value;
       stamp_start;
       stamp_expire_withdraw;
       stamp_expire_deposit;
       stamp_expire_legal;
       fee_withdraw;
       fee_deposit;
       fee_refresh;
       fee_refund;
       age_mask;
       h_pub;
       master_sig= _;
     } :
      Denomination.t) =
  let denom_pub =
    DenominationKey.of_rsa RsaDenominationKey.{ age_mask; rsa_pub= pub }
  in
  let denom_secmod_sig =
    let open Bin_signature.DenominationKeyAnnouncementPS in
    let h_denom_pub = h_pub in
    let h_section_name = Bin_type.Hash_64_cstr.hash section_name in
    let anchor_time = stamp_start in
    let duration_withdraw =
      Timestamp.diff stamp_start stamp_expire_withdraw |> Timestamp.of_span_exn
    in
    sign ~key { h_denom_pub; h_section_name; anchor_time; duration_withdraw }
  in
  FutureDenom.
    {
      section_name;
      value;
      stamp_start;
      stamp_expire_withdraw;
      stamp_expire_deposit;
      stamp_expire_legal;
      denom_pub;
      fee_withdraw;
      fee_deposit;
      fee_refresh;
      fee_refund;
      denom_secmod_sig;
    }

let mk_future_signkey ~key
    ({ pub; priv= _; stamp_start; stamp_expire; stamp_end; master_sig= _ } :
      Signkey.t) =
  let signkey_secmod_sig =
    let open Bin_signature.SigningKeyAnnouncementPS in
    let exchange_pub = pub in
    let anchor_time = stamp_start in
    let duration =
      Timestamp.diff stamp_start stamp_expire |> Timestamp.of_span_exn
    in
    sign ~key { exchange_pub; anchor_time; duration }
  in
  FutureSignKey.
    { key= pub; stamp_start; stamp_expire; stamp_end; signkey_secmod_sig }

let mk_future_keys_response (secmod_signkey : Secmod_signkey.t)
    (secmod_denom : Secmod_denom.t) =
  let future_denoms =
    secmod_denom.keys
    |> List.filter (fun k -> Option.is_none k.Denomination.master_sig)
    |> List.map (fun denom ->
        let key = secmod_denom.sm_key.Signkey.priv in
        mk_future_denom ~key denom)
  in
  let future_signkeys =
    secmod_signkey.keys
    |> List.filter (fun k -> Option.is_none k.Signkey.master_sig)
    |> List.map (fun signkey ->
        let key = secmod_denom.sm_key.Signkey.priv in
        mk_future_signkey ~key signkey)
  in
  let master_pub = Config.Exchange.master_public_key in
  let denom_secmod_public_key = secmod_denom.sm_key.pub in
  let signkey_secmod_public_key = secmod_signkey.sm_key.pub in
  FutureKeysResponse.
    {
      future_denoms;
      future_signkeys;
      master_pub;
      denom_secmod_public_key;
      signkey_secmod_public_key;
    }

let keys_get req server _env =
  let open Vif.Response in
  let open Syntax in
  let secmod_signkey = Vif.Server.device Devices.secmod_signkey server in
  let secmod_denom = Vif.Server.device Devices.secmod_denom server in
  let v = mk_future_keys_response secmod_signkey secmod_denom in
  let s = Api.encode_exn Api.FutureKeysResponse.jsont v in
  let* () = with_string req s in
  let* () = add ~field:"content-type" "application/json" in
  respond `OK