clean up tos

tools/dbinit.sh

@@ -0,0 +1,100 @@
+#!/bin/bash
+
+# TODO
+# use specific commit
+
+# usage:
+#   `create_database`
+#      create a `taler-exchange` database
+#   `fetch`
+#      fetch all *.sql and *.sql.in files from GNU Taler exchange repository (latest commit)
+#   `init`
+#      initialize taler-exchange database (create tables, ...)
+#      `taler-exchange` database must already be created
+#
+
+
+set -e
+
+taler_repo_url="https://git-www.taler.net/exchange.git/"
+
+tmp_dir="/tmp/taler_exchange"
+out_dir="./_taler_exchange_sql"
+init_sql="${out_dir}/init.sql"
+drop_sql="${out_dir}/drop.sql"
+
+# psql parameter
+host="localhost"
+port=5432
+username="mte"
+dbname="taler-exchange"
+
+fetch() {
+   git clone --depth 1 $taler_repo_url $tmp_dir
+}
+
+process() {
+   source_dir="${tmp_dir}/src/exchangedb"
+   sql_in_files=(
+     "procedures.sql"
+     "exchange-0002.sql"
+     "exchange-0003.sql"
+     "exchange-0004.sql"
+   )
+   for file in "${sql_in_files[@]}"; do
+     file_in="${source_dir}/${file}.in"
+     file_out="${source_dir}/${file}"
+     gcc -E -P -undef -I "$source_dir" - < "$file_in" \
+       2>/dev/null \
+       > "$file_out"
+   done
+   # order is important
+   files=(
+     "versioning.sql"
+     "exchange-0001.sql"
+     "exchange-0002.sql"
+     "exchange-0003.sql"
+     "exchange-0004.sql"
+     "exchange-0005.sql"
+     "procedures.sql"
+   )
+   mkdir -p "$out_dir"
+   cat "${source_dir}/drop.sql" > "$drop_sql"
+   echo "" > "$init_sql"
+   for file in "${files[@]}"; do
+      cat "${source_dir}/${file}" >> "$init_sql"
+   done
+}
+
+# ? "NOTICE:  function xxx() does not exist, skipping"
+init() {
+   psql --host=$host --port=$port --username=$username --password --dbname=$dbname --file=$init_sql
+}
+
+drop_schema() {
+   psql --host=$host --port=$port --username=$username --password --dbname=$dbname --file=$drop_sql
+}
+
+create_database() {
+   createdb --host=$host --port=$port --username=$username --password $dbname
+}
+
+drop_database() {
+   dropdb --host=$host --port=$port --username=$username --password $dbname
+}
+
+if [[ $# -eq 0 ]]; then
+    echo "no argument" >&2
+    exit 1
+fi
+
+cmd=$1
+case "$cmd" in
+    fetch) fetch "$@"; exit 0;;
+    process) process "$@"; exit 0;;
+    init) init "$@"; exit 0;;
+    drop_schema) drop_schema "$@"; exit 0;;
+    create_database) create_database "$@"; exit 0;;
+    drop_database) drop_database "$@"; exit 0;;
+    *) echo "Unknown command: $cmd" >&2; exit 1;;
+esac

tools/dune

@@ -0,0 +1,11 @@
+(executable
+ (public_name offline)
+ (name offline)
+ (modules offline offline_impl)
+ (libraries cmdliner bos fmt mirage-crypto ptime mte vif))
+
+(executable
+ (public_name gen_signatures_registry)
+ (name gen_signatures_registry)
+ (modules gen_signatures_registry)
+ (libraries angstrom bos fmt))

tools/gen_signatures_registry.ml

@@ -0,0 +1,109 @@
+module Recfile = struct
+  (* rudimentary recfile parser
+     https://www.gnu.org/software/recutils/manual/recutils.html#The-Rec-Format *)
+  open Angstrom
+
+  type field = {
+    k: string;
+    v: string;
+  }
+
+  type record = field list
+
+  let newline = char '\n'
+  let is_newline = function '\n' -> true | _ -> false
+
+  let field_name =
+    let first_char =
+      satisfy (function 'a' .. 'z' | 'A' .. 'Z' | '%' -> true | _ -> false)
+    in
+    let subsequent_char =
+      satisfy (function
+        | 'a' .. 'z' | 'A' .. 'Z' | '0' .. '9' | '_' -> true
+        | _ -> false)
+    in
+    lift2
+      (fun hd tl -> String.of_seq (List.to_seq (hd :: tl)))
+      first_char (many subsequent_char)
+
+  (* todo handle '\' escape and '+' on next line *)
+  let field_value = take_till is_newline <* newline
+
+  let field =
+    let blank = satisfy (function ' ' | '\t' -> true | _ -> false) in
+    let blanks = skip_many1 blank in
+    lift3 (fun k () v -> { k; v }) field_name (char ':' *> blanks) field_value
+
+  let blank = newline *> return ()
+  let comment = (char '#' *> take_till is_newline <* newline) *> return ()
+  let record = many1 field
+
+  let records =
+    let sep =
+      (* at least one blank line *)
+      skip_many comment *> blank *> skip_many (comment <|> blank)
+    in
+    sep_by1 sep record
+
+  let recfile : record list t =
+    skip_many (comment <|> blank) *> records <* skip_many (comment <|> blank)
+
+  let parse s = parse_string ~consume:All recfile s
+end
+
+let url =
+  "https://git-www.gnunet.org/gana.git/plain/gnunet-signatures/registry.rec"
+
+let registry_file = "registry.rec"
+
+let download () =
+  let open Bos in
+  let res =
+    OS.Cmd.run Cmd.(v "curl" % "-s" % "-o" % registry_file % "-X" % "GET" % url)
+  in
+  match res with
+  | Error (`Msg s) -> Fmt.failwith "download failure: %s" s
+  | Ok () -> ()
+
+let read_file file = In_channel.with_open_bin file In_channel.input_all
+
+type purpose = {
+  number: int32;
+  name: string;
+  comment: string;
+}
+
+let parse_purposes records =
+  records
+  |> List.filter_map (fun l ->
+      match l with
+      | a :: b :: c :: _ -> (
+          let open Recfile in
+          match a.k = "Number" && b.k = "Name" && c.k = "Comment" with
+          | false -> None
+          | true ->
+              Some
+                {
+                  number= Int32.of_int (int_of_string a.v);
+                  name= String.lowercase_ascii b.v;
+                  comment= c.v;
+                })
+      | _ -> None)
+  |> List.filter (fun v -> v.number >= 1000_l)
+
+let () =
+  download ();
+  let content = read_file registry_file in
+  match Recfile.parse content with
+  | Error msg -> Fmt.failwith "Recfile parse error: %s" msg
+  | Ok records ->
+      let purposes = parse_purposes records in
+      let header =
+        {|(* This file was generated from the GANA database:
+   https://git-www.gnunet.org/gana.git/tree/gnunet-signatures/registry.rec *)|}
+      in
+      let pp ppf { number; name; comment } =
+        Fmt.pf ppf "(** %s *)\nlet %s : int32 = %ld_l\n\n" comment name number
+      in
+      Fmt.pr "%s\n\n%a@." header (Fmt.list ~sep:Fmt.nop pp) purposes;
+      ()

tools/offline.ml

@@ -0,0 +1,301 @@
+(* TODO
+   better cmd doc
+   change arguments: '_' -> '-'
+
+   all management operations:
+     /management/wire
+     /management/wire/disable
+       -> how to build WireSetupMessage?
+          we need additional data to craft master_sig
+          maybe supposed to be found in the full payto-uri?
+
+     /management/aml-officers
+       -> /aml
+     /management/partners
+       -> /wads *)
+
+open Cmdliner
+open Cmdliner.Term.Syntax
+open Offline_impl
+
+module Arg = struct
+  include Arg
+
+  (* in seconds *)
+  let timestamp =
+    let parser s =
+      match int_of_string_opt s with
+      | None -> Error "not an int"
+      | Some n -> Ok (Time.Timestamp.of_s (Int64.of_int n))
+    in
+    let pp fmt t =
+      match Time.Timestamp.to_s t with
+      | None -> Fmt.pf fmt "never"
+      | Some s -> Fmt.pf fmt "%Ld" s
+    in
+    Arg.Conv.make ~docv:"timestamp argument" ~parser ~pp ()
+
+  (* in seconds *)
+  let relative_time =
+    let parser s =
+      match int_of_string_opt s with
+      | None -> Error "not an int"
+      | Some s -> Ok (Time.Relative.of_s (Int64.of_int s))
+    in
+    let pp fmt d =
+      let t = Time.Timestamp.of_absolute Time.Absolute.(add zero d) in
+      match Time.Timestamp.to_s t with
+      | None -> Fmt.pf fmt "never"
+      | Some s -> Fmt.pf fmt "%Ld" s
+    in
+    Arg.Conv.make ~docv:"relative time argument" ~parser ~pp ()
+
+  let b32 =
+    let pp fmt v = Fmt.pf fmt "%s" (B32.encode v) in
+    Arg.Conv.make ~docv:"Crockford's Base32 encoded argument" ~parser:B32.decode
+      ~pp ()
+
+  let amount =
+    Arg.Conv.make ~docv:"amount argument" ~parser:Amount.of_string ~pp:Amount.pp
+      ()
+
+  let eddsa_pub =
+    let parser s = Crypto.EddsaPublicKey.of_b32 s in
+    let pp fmt key =
+      let s = Crypto.EddsaPublicKey.to_b32 key in
+      Fmt.pf fmt "%s" s
+    in
+    Arg.Conv.make ~docv:"eddsa public key argument" ~parser ~pp ()
+end
+
+let master_key =
+  let doc = "Master offline Eddsa private key file." in
+  Arg.(required & opt (some file) None & info [ "master_key" ] ~doc)
+
+let input =
+  let doc = "input file" in
+  Arg.(required & opt (some file) None & info [ "i"; "input" ] ~doc)
+
+let output =
+  let doc = "output file" in
+  Arg.(required & opt (some filepath) None & info [ "o"; "output" ] ~doc)
+
+let url =
+  let doc = "url" in
+  Arg.(required & opt (some string) None & info [ "url" ] ~doc)
+
+let setup_cmd =
+  let doc = "Generate offline master keys" in
+  let output =
+    let doc = "output file" in
+    Arg.(required & opt (some filepath) None & info [ "o"; "output" ] ~doc)
+  in
+  Cmd.make (Cmd.info "setup" ~doc)
+  @@
+  let+ output = output in
+  setup ~output
+
+let download_cmd =
+  let doc = "GET" in
+  Cmd.make (Cmd.info "download" ~doc)
+  @@
+  let+ output = output and+ url = url in
+  download ~output ~url
+
+let upload_cmd =
+  let doc = "POST" in
+  Cmd.make (Cmd.info "upload" ~doc)
+  @@
+  let+ input = input and+ url = url in
+  upload ~input ~url
+
+let sign_cmd =
+  let doc = "Sign FutureKeysResponse." in
+  Cmd.make (Cmd.info "sign" ~doc)
+  @@
+  let+ input = input and+ output = output and+ master_key = master_key in
+  sign ~input ~output ~master_key
+
+let revoke_denom_cmd =
+  let doc = "Revoke denomination." in
+  let h_denom =
+    let doc = "hash of denomination public key" in
+    Arg.(required & pos 0 (some string) None & info [] ~doc)
+  in
+  Cmd.make (Cmd.info "revoke-denom" ~doc)
+  @@
+  let+ output = output and+ master_key = master_key and+ h_denom = h_denom in
+  revoke_denom ~output ~master_key ~h_denom
+
+let revoke_signkey_cmd =
+  let doc = "Revoke signkey." in
+  let signkey =
+    let doc = "public signing key" in
+    Arg.(required & pos 0 (some eddsa_pub) None & info [] ~doc)
+  in
+  Cmd.make (Cmd.info "revoke-signkey" ~doc)
+  @@
+  let+ output = output and+ master_key = master_key and+ signkey = signkey in
+  revoke_signkey ~output ~master_key ~signkey
+
+let enable_auditor_cmd =
+  let doc = "Enable auditor." in
+  let auditor_url =
+    Arg.(required & opt (some string) None & info [ "auditor_url" ])
+  in
+  let auditor_name =
+    Arg.(required & opt (some string) None & info [ "auditor_name" ])
+  in
+  let auditor_pub =
+    Arg.(required & opt (some eddsa_pub) None & info [ "auditor_pub" ])
+  in
+  let validity_start =
+    Arg.(required & opt (some timestamp) None & info [ "validity_start" ])
+  in
+  Cmd.make (Cmd.info "enable-auditor" ~doc)
+  @@
+  let+ output = output
+  and+ master_key = master_key
+  and+ auditor_url = auditor_url
+  and+ auditor_name = auditor_name
+  and+ auditor_pub = auditor_pub
+  and+ validity_start = validity_start in
+  enable_auditor ~output ~master_key ~auditor_url ~auditor_name ~auditor_pub
+    ~validity_start
+
+let disable_auditor_cmd =
+  let doc = "Disable auditor." in
+  let auditor_pub =
+    Arg.(required & opt (some eddsa_pub) None & info [ "auditor_pub" ])
+  in
+  let validity_end =
+    Arg.(required & opt (some timestamp) None & info [ "validity_end" ])
+  in
+  Cmd.make (Cmd.info "disable-auditor" ~doc)
+  @@
+  let+ output = output
+  and+ master_key = master_key
+  and+ auditor_pub = auditor_pub
+  and+ validity_end = validity_end in
+  disable_auditor ~output ~master_key ~auditor_pub ~validity_end
+
+let wire_fee_cmd =
+  let doc = "Provides wire fee configuration." in
+  let wire_method =
+    Arg.(required & opt (some string) None & info [ "wire_method" ])
+  in
+  let fee_start =
+    Arg.(required & opt (some timestamp) None & info [ "fee_start" ])
+  in
+  let fee_end =
+    Arg.(required & opt (some timestamp) None & info [ "fee_end" ])
+  in
+  let closing_fee =
+    Arg.(required & opt (some amount) None & info [ "closing_fee" ])
+  in
+  let wire_fee =
+    Arg.(required & opt (some amount) None & info [ "wire_fee" ])
+  in
+  Cmd.make (Cmd.info "wire-fee" ~doc)
+  @@
+  let+ output = output
+  and+ master_key = master_key
+  and+ wire_method = wire_method
+  and+ fee_start = fee_start
+  and+ fee_end = fee_end
+  and+ closing_fee = closing_fee
+  and+ wire_fee = wire_fee in
+  Offline_impl.wire_fee ~output ~master_key ~wire_method ~fee_start ~fee_end
+    ~closing_fee ~wire_fee
+
+let global_fees_cmd =
+  let doc = "Provides global fee configuration." in
+  let start_date =
+    Arg.(required & opt (some timestamp) None & info [ "start_date" ])
+  in
+  let end_date =
+    Arg.(required & opt (some timestamp) None & info [ "end_date" ])
+  in
+  let history_fee =
+    Arg.(required & opt (some amount) None & info [ "history_fee" ])
+  in
+  let account_fee =
+    Arg.(required & opt (some amount) None & info [ "account_fee" ])
+  in
+  let purse_fee =
+    Arg.(required & opt (some amount) None & info [ "purse_fee" ])
+  in
+  let history_expiration =
+    Arg.(
+      required & opt (some relative_time) None & info [ "history_expiration" ])
+  in
+  let purse_account_limit =
+    Arg.(required & opt (some int) None & info [ "purse_account_limit" ])
+  in
+  let purse_timeout =
+    Arg.(required & opt (some relative_time) None & info [ "purse_timeout" ])
+  in
+  Cmd.make (Cmd.info "global-fees" ~doc)
+  @@
+  let+ output = output
+  and+ master_key = master_key
+  and+ start_date = start_date
+  and+ end_date = end_date
+  and+ history_fee = history_fee
+  and+ account_fee = account_fee
+  and+ purse_fee = purse_fee
+  and+ history_expiration = history_expiration
+  and+ purse_account_limit = purse_account_limit
+  and+ purse_timeout = purse_timeout in
+  global_fees ~output ~master_key ~start_date ~end_date ~history_fee
+    ~account_fee ~purse_fee ~history_expiration ~purse_account_limit
+    ~purse_timeout
+
+let drain_cmd =
+  let doc =
+    "Drain profits from the exchange. The actual drain requires running the \
+     `taler-exchange-drain` tool."
+  in
+  let debit_account_section =
+    Arg.(required & opt (some string) None & info [ "debit_account_section" ])
+  in
+  let credit_payto_uri =
+    Arg.(required & opt (some string) None & info [ "credit_payto_uri" ])
+  in
+  let wtid = Arg.(required & opt (some b32) None & info [ "wtid" ]) in
+  let date = Arg.(required & opt (some timestamp) None & info [ "date" ]) in
+  let amount = Arg.(required & opt (some amount) None & info [ "amount" ]) in
+  Cmd.make (Cmd.info "drain" ~doc)
+  @@
+  let+ output = output
+  and+ master_key = master_key
+  and+ debit_account_section = debit_account_section
+  and+ credit_payto_uri = credit_payto_uri
+  and+ wtid = wtid
+  and+ date = date
+  and+ amount = amount in
+  drain ~output ~master_key ~debit_account_section ~credit_payto_uri ~wtid ~date
+    ~amount
+
+let cli =
+  let info =
+    let doc = "MTE Offline CLI tool" in
+    Cmd.info "mte-offline" ~doc
+  in
+  Cmd.group info
+    [
+      setup_cmd;
+      download_cmd;
+      sign_cmd;
+      upload_cmd;
+      revoke_denom_cmd;
+      revoke_signkey_cmd;
+      enable_auditor_cmd;
+      disable_auditor_cmd;
+      wire_fee_cmd;
+      global_fees_cmd;
+      drain_cmd;
+    ]
+
+let main () = Cmd.eval_result cli
+let () = if !Sys.interactive then () else exit (main ())

tools/offline_impl.ml

@@ -0,0 +1,368 @@
+open Syntax
+open Hash
+
+module Future_keys = struct
+  open Crypto
+  open Api
+
+  let verify =
+    let verify_future_denom ~sm_denom_pub
+        FutureDenom.
+          {
+            section_name;
+            value= _;
+            stamp_start;
+            stamp_expire_withdraw;
+            stamp_expire_deposit= _;
+            stamp_expire_legal= _;
+            denom_pub;
+            fee_withdraw= _;
+            fee_deposit= _;
+            fee_refresh= _;
+            fee_refund= _;
+            denom_secmod_sig;
+          } =
+      let h_denom_pub =
+        DenominationHash.hash (DenominationKey.to_octets denom_pub)
+      in
+      let h_section_name = Hash.Cstring.H64.hash section_name in
+      let anchor_time = stamp_start in
+      let duration_withdraw =
+        Timestamp.diff stamp_start stamp_expire_withdraw
+      in
+      let open Signatures.DenominationKeyAnnouncement in
+      verify_f
+        ~f:(EddsaSignature.verify ~key:sm_denom_pub)
+        denom_secmod_sig
+        { h_denom_pub; h_section_name; anchor_time; duration_withdraw }
+    in
+    let verify_future_signkey ~sm_signkey_pub
+        FutureSignKey.
+          { key; stamp_start; stamp_expire; stamp_end= _; signkey_secmod_sig } =
+      let exchange_pub = key in
+      let anchor_time = stamp_start in
+      let duration = Timestamp.diff stamp_start stamp_expire in
+      let open Signatures.SigningKeyAnnouncement in
+      verify_f
+        ~f:(EddsaSignature.verify ~key:sm_signkey_pub)
+        signkey_secmod_sig
+        { exchange_pub; anchor_time; duration }
+    in
+    fun our_master_public_key
+      FutureKeysResponse.
+        {
+          future_denoms;
+          future_signkeys;
+          master_pub;
+          denom_secmod_public_key;
+          signkey_secmod_public_key;
+        }
+    ->
+      let* () =
+        match master_pub = our_master_public_key with
+        | false ->
+            Fmt.error
+              "master public key of the future key response does not match ours"
+        | true -> Ok ()
+      in
+      let* () =
+        list_iter
+          (verify_future_denom ~sm_denom_pub:denom_secmod_public_key)
+          future_denoms
+      in
+      let* () =
+        list_iter
+          (verify_future_signkey ~sm_signkey_pub:signkey_secmod_public_key)
+          future_signkeys
+      in
+      Ok ()
+
+  let make =
+    let denom_signature ~master_key
+        FutureDenom.
+          {
+            section_name= _;
+            value;
+            stamp_start;
+            stamp_expire_withdraw;
+            stamp_expire_deposit;
+            stamp_expire_legal;
+            denom_pub;
+            fee_withdraw;
+            fee_deposit;
+            fee_refresh;
+            fee_refund;
+            denom_secmod_sig= _;
+          } =
+      let octets = DenominationKey.to_octets denom_pub in
+      let h_denom_pub = DenominationHash.hash octets in
+      let master_sig =
+        let open Signatures.DenominationKeyValidity in
+        let master = EddsaPrivateKey.(pub_of_priv master_key) in
+        sign_f
+          ~f:(EddsaSignature.sign ~key:master_key)
+          {
+            master;
+            start= stamp_start;
+            expire_withdraw= stamp_expire_withdraw;
+            expire_spend= stamp_expire_deposit;
+            expire_legal= stamp_expire_legal;
+            value;
+            fee_withdraw;
+            fee_deposit;
+            fee_refresh;
+            fee_refund;
+            denom_hash= h_denom_pub;
+          }
+      in
+      DenomSignature.{ h_denom_pub; master_sig }
+    in
+    let signkey_signature ~master_key
+        FutureSignKey.
+          { key; stamp_start; stamp_expire; stamp_end; signkey_secmod_sig= _ } =
+      let master_sig =
+        let open Signatures.ExchangeSigningKeyValidity in
+        sign_f
+          ~f:(EddsaSignature.sign ~key:master_key)
+          {
+            start= stamp_start;
+            expire= stamp_expire;
+            end_= stamp_end;
+            signkey_pub= key;
+          }
+      in
+      SignKeySignature.{ key; master_sig }
+    in
+    fun ~master_key
+      FutureKeysResponse.
+        {
+          future_denoms;
+          future_signkeys;
+          master_pub= _;
+          denom_secmod_public_key= _;
+          signkey_secmod_public_key= _;
+        }
+    ->
+      let denom_sigs = List.map (denom_signature ~master_key) future_denoms in
+      let signkey_sigs =
+        List.map (signkey_signature ~master_key) future_signkeys
+      in
+      MasterSignatures.{ denom_sigs; signkey_sigs }
+end
+
+(* -- *)
+
+let read_file fname = Bos.OS.File.read (Fpath.v fname) |> unwrap_err_msg
+
+let write_file fname content =
+  Bos.OS.File.write (Fpath.v fname) content |> unwrap_err_msg
+
+let read_master_key_file filename =
+  let* master_key = read_file filename in
+  Crypto.EddsaPrivateKey.of_octets master_key
+
+let download ~output ~url =
+  let open Bos in
+  OS.Cmd.run Cmd.(v "curl" % "--silent" % "-o" % output % "-X" % "GET" % url)
+  |> unwrap_err_msg
+
+let upload ~input ~url =
+  let open Bos in
+  OS.Cmd.run
+    Cmd.(
+      v "curl"
+      % "--silent"
+      % "-i"
+      % "-X"
+      % "POST"
+      % "-H"
+      % "Content-Type: application/json"
+      % "--data"
+      % ("@" ^ input)
+      % url)
+  |> unwrap_err_msg
+
+let setup ~output =
+  let () = Mirage_crypto_rng_unix.use_default () in
+  let priv, pub = Mirage_crypto_ec.Ed25519.generate () in
+  Fmt.pr "generated master public key:@\n%s@."
+    (Mirage_crypto_ec.Ed25519.pub_to_octets pub |> B32.encode);
+  let priv_data = Mirage_crypto_ec.Ed25519.priv_to_octets priv in
+  write_file output priv_data
+
+let sign ~master_key ~input ~output =
+  let open Crypto in
+  let* master_key = read_master_key_file master_key in
+  let* input = read_file input in
+  let master_pub = EddsaPrivateKey.pub_of_priv master_key in
+  let* future_keys_response = Api.decode Api.FutureKeysResponse.jsont input in
+  let* () = Future_keys.verify master_pub future_keys_response in
+  let master_signatures = Future_keys.make ~master_key future_keys_response in
+  let* s = Api.encode Api.MasterSignatures.jsont master_signatures in
+  let* () = write_file output s in
+  Ok ()
+
+let revoke_denom ~output ~master_key ~h_denom =
+  let* key = read_master_key_file master_key in
+  let* h_denom_pub = DenominationHash.of_b32 h_denom in
+  let denom_revoke =
+    let master_sig =
+      let open Signatures.MasterDenominationKeyRevocation in
+      sign_f ~f:(Crypto.EddsaSignature.sign ~key) { h_denom_pub }
+    in
+    Api.DenomRevocationSignature.{ master_sig }
+  in
+  let* s = Api.encode Api.DenomRevocationSignature.jsont denom_revoke in
+  let* () = write_file output s in
+  Ok ()
+
+let revoke_signkey ~output ~master_key ~signkey =
+  let* key = read_master_key_file master_key in
+  let signkey_revoke =
+    let master_sig =
+      let open Signatures.MasterSigningKeyRevocation in
+      sign_f ~f:(Crypto.EddsaSignature.sign ~key) { exchange_pub= signkey }
+    in
+    Api.SignkeyRevocationSignature.{ master_sig }
+  in
+  let* s = Api.encode Api.SignkeyRevocationSignature.jsont signkey_revoke in
+  let* () = write_file output s in
+  Ok ()
+
+let global_fees ~output ~master_key ~start_date ~end_date ~history_fee
+    ~account_fee ~purse_fee ~history_expiration ~purse_account_limit
+    ~purse_timeout =
+  let open Crypto in
+  let* key = read_master_key_file master_key in
+  let* purse_account_limit =
+    match
+      purse_account_limit >= 0
+      && purse_account_limit <= Int32.to_int Int32.max_int
+    with
+    | false -> Error "invalid purse_account_limit value"
+    | true -> Ok (Int32.of_int purse_account_limit)
+  in
+  let master_sig =
+    let open Signatures.GlobalFees in
+    sign_f ~f:(EddsaSignature.sign ~key)
+      {
+        start_date;
+        end_date;
+        purse_timeout;
+        history_expiration;
+        history_fee;
+        account_fee;
+        purse_fee;
+        purse_account_limit;
+      }
+  in
+  let global_fees =
+    Api.GlobalFees.
+      {
+        start_date;
+        end_date;
+        purse_timeout;
+        history_expiration;
+        history_fee;
+        account_fee;
+        purse_fee;
+        purse_account_limit;
+        master_sig;
+      }
+  in
+  let* s = Api.encode Api.GlobalFees.jsont global_fees in
+  let* () = write_file output s in
+  Ok ()
+
+let enable_auditor ~output ~master_key ~auditor_url ~auditor_name ~auditor_pub
+    ~validity_start =
+  let open Crypto in
+  let* key = read_master_key_file master_key in
+  let master_sig =
+    let open Signatures.MasterAddAuditor in
+    sign_f ~f:(EddsaSignature.sign ~key)
+      {
+        start_date= validity_start;
+        auditor_pub;
+        h_auditor_url= Hash.Cstring.H64.hash auditor_url;
+      }
+  in
+  let v =
+    Api.AuditorSetupMessage.
+      { auditor_url; auditor_name; auditor_pub; master_sig; validity_start }
+  in
+  let* s = Api.encode Api.AuditorSetupMessage.jsont v in
+  let* () = write_file output s in
+  Ok ()
+
+let disable_auditor ~output ~master_key ~auditor_pub ~validity_end =
+  let open Crypto in
+  let* key = read_master_key_file master_key in
+  let master_sig =
+    let open Signatures.MasterDelAuditor in
+    sign_f ~f:(EddsaSignature.sign ~key) { end_date= validity_end; auditor_pub }
+  in
+  let v = Api.AuditorTeardownMessage.{ master_sig; validity_end } in
+  let* s = Api.encode Api.AuditorTeardownMessage.jsont v in
+  let* () = write_file output s in
+  Ok ()
+
+let wire_fee ~output ~master_key ~wire_method ~fee_start ~fee_end ~closing_fee
+    ~wire_fee =
+  let open Crypto in
+  let* key = read_master_key_file master_key in
+  let master_sig_wire =
+    let open Signatures.MasterWireFee in
+    sign_f ~f:(EddsaSignature.sign ~key)
+      {
+        h_wire_method= Hash.Cstring.H64.hash wire_method;
+        start_date= fee_start;
+        end_date= fee_end;
+        closing_fee;
+        wire_fee;
+      }
+  in
+  let v =
+    Api.WireFeeSetupMessage.
+      {
+        wire_method;
+        fee_start;
+        fee_end;
+        closing_fee;
+        wire_fee;
+        master_sig_wire;
+      }
+  in
+  let* s = Api.encode Api.WireFeeSetupMessage.jsont v in
+  let* () = write_file output s in
+  Ok ()
+
+let drain ~output ~master_key ~debit_account_section ~credit_payto_uri ~wtid
+    ~date ~amount =
+  let open Crypto in
+  let* key = read_master_key_file master_key in
+  let master_sig =
+    let open Signatures.MasterDrainProfit in
+    sign_f ~f:(EddsaSignature.sign ~key)
+      {
+        wtid;
+        date;
+        amount;
+        h_section= Hash.Cstring.H64.hash debit_account_section;
+        h_payto= FullPaytoHash.hash credit_payto_uri;
+      }
+  in
+  let v =
+    Api.DrainProfitsMessage.
+      {
+        debit_account_section;
+        credit_payto_uri;
+        wtid;
+        master_sig;
+        date;
+        amount;
+      }
+  in
+  let* s = Api.encode Api.DrainProfitsMessage.jsont v in
+  let* () = write_file output s in
+  Ok ()