mte/tools/offline.ml

(* TODO
   - clean up cmdliner
   - setup: need public key in config file
   - check sigs *)
(* doc: https://docs.taler.net/manpages/taler-exchange-offline.1.html *)

open Syntax

let version = "%%VERSION%%"
let base_url = Uri.of_string "http://localhost:3434/"
let read_file fname = Bos.OS.File.read (Fpath.v fname) |> unwrap_err_msg

let write_file fname content =
  Bos.OS.File.write (Fpath.v fname) content |> unwrap_err_msg

let download ~output =
  let open Bos in
  let uri = Uri.with_path base_url "/management/keys/" |> Uri.to_string in
  OS.Cmd.run Cmd.(v "curl" % "-s" % "-o" % output % "-X" % "GET" % uri)

let upload ~input =
  let open Bos in
  let uri = Uri.with_path base_url "/management/keys/" |> Uri.to_string in
  OS.Cmd.run
    Cmd.(
      v "curl"
      % "-i"
      % "-X"
      % "POST"
      % "-H"
      % "Content-Type: application/json"
      % "--data"
      % ("@" ^ input)
      % uri)

let setup ~output =
  let () = Mirage_crypto_rng_unix.use_default () in
  let priv, pub = Mirage_crypto_ec.Ed25519.generate () in
  Fmt.pr "generated master public key:@\n%s@."
    (Mirage_crypto_ec.Ed25519.pub_to_octets pub |> B32.encode);
  let priv_data = Mirage_crypto_ec.Ed25519.priv_to_octets priv in
  write_file output priv_data

let sign ~master_key ~input ~output =
  let open Crypto in
  let* input = read_file input in
  let* master_key = read_file master_key in
  let master_key = EddsaPrivateKey.of_octets master_key in
  let* future_key_response = Api.decode Api.FutureKeysResponse.jsont input in
  let* () = Offline_bin.verify_future_key_response future_key_response in
  let master_signatures =
    Offline_bin.make_master_signatures ~master_key future_key_response
  in
  let* s = Api.encode Api.MasterSignatures.jsont master_signatures in
  let* () = write_file output s in
  Ok ()

(* CLI *)

open Cmdliner
open Cmdliner.Term.Syntax

let default_master_offline_key_file = "data/master_offline_private_key"
let default_response_file = "response.json"
let default_request_file = "request.json"
let to_term_ret = function Error e -> `Error (false, e) | Ok () -> `Ok ()

let setup_cmd =
  let doc = "Generate offline master keys" in
  let output =
    Arg.(
      value
      & opt filepath default_master_offline_key_file
      & info [ "o"; "output" ] ~doc)
  in
  Cmd.make (Cmd.info "setup" ~version ~doc)
  @@ Term.ret
  @@
  let+ output = output in
  setup ~output |> to_term_ret

let download_cmd =
  let doc = "GET /management/keys/" in
  let man =
    [ `S Manpage.s_description; `P "$(cmd) download /management/keys." ]
  in
  let output =
    Arg.(
      value & opt filepath default_response_file & info [ "o"; "output" ] ~doc)
  in
  Cmd.make (Cmd.info "download" ~version ~doc ~man)
  @@ Term.ret
  @@
  let+ output = output in
  download ~output |> unwrap_err_msg |> to_term_ret

let upload_cmd =
  let doc = "POST /management/keys/" in
  let man =
    [ `S Manpage.s_description; `P "$(cmd) upload /management/keys." ]
  in
  let input =
    Arg.(value & opt file default_request_file & info [ "i"; "input" ] ~doc)
  in
  Cmd.make (Cmd.info "upload" ~version ~doc ~man)
  @@ Term.ret
  @@
  let+ input = input in
  upload ~input |> unwrap_err_msg |> to_term_ret

let sign_cmd =
  let doc = "Sign FutureKeysResponse." in
  let master_key =
    let doc = "Master offline Eddsa private key file." in
    Arg.(value & opt file default_master_offline_key_file & info [ "key" ] ~doc)
  in
  let input =
    Arg.(value & opt file default_response_file & info [ "i"; "input" ] ~doc)
  in
  let output =
    Arg.(
      value & opt filepath default_request_file & info [ "o"; "output" ] ~doc)
  in
  Cmd.make (Cmd.info "sign" ~version ~doc)
  @@ Term.ret
  @@
  let+ input = input and+ output = output and+ master_key = master_key in
  sign ~input ~output ~master_key |> to_term_ret

let cli =
  let info =
    let doc = "MTE Offline CLI tool" in
    Cmd.info "mte-offline" ~version ~doc
  in
  Cmd.group info [ setup_cmd; download_cmd; sign_cmd; upload_cmd ]

let main () = Cmd.eval cli
let () = if !Sys.interactive then () else exit (main ())