mte/src/secmod_eddsa.ml

let src = Logs.Src.create "mte.secmod_eddsa"

module Log = (val Logs.src_log src : Logs.LOG)

(* - *)
open Syntax
open Crypto
open Time
module Cfg = Config.Exchange_secmod_eddsa

type key = {
  priv: EddsaPrivateKey.t;
  pub: EddsaPublicKey.t;
  t1: TimeAbsolute.t;
  t2: TimeAbsolute.t;
}

type t = {
  sm_key_priv: EddsaPrivateKey.t;
  sm_pub: EddsaPublicKey.t;
  ht: (EddsaPublicKey.t, key) Hashtbl.t;
}

let parse_filename =
  let scan_filename s =
    Scanf.sscanf_opt s "%Lu-%Lu" (fun t1 t2 ->
        (TimeAbsolute.of_s t1, TimeAbsolute.of_s t2))
  in
  fun fpath -> scan_filename (Fpath.filename fpath)

let pp_filename =
  let to_int64 abs =
    abs |> Timestamp.of_absolute |> Timestamp.to_s |> function
    | None ->
        (* (= `never`) this should not happen given resonable config value *)
        Fmt.failwith "encountered timestamp with value `never`"
    | Some i -> i
  in
  fun ppf (t1, t2) -> Fmt.pf ppf "%Lu-%Lu" (to_int64 t1) (to_int64 t2)

let key_fpath k =
  let fname = Fmt.str "%a" pp_filename (k.t1, k.t2) in
  Fpath.(v Cfg.key_dir / fname)

(* -- IO -- *)

let read_key fpath =
  Log.debug (fun m -> m "reading key file `%a`" Fpath.pp fpath);
  let* data = Bos.OS.File.read fpath |> unwrap_err_msg in
  EddsaPrivateKey.of_octets data

let write_eddsa fpath priv =
  Log.debug (fun m -> m "writing key file `%a`" Fpath.pp fpath);
  let data = EddsaPrivateKey.to_octets priv in
  Bos.OS.File.write fpath data |> unwrap_err_msg

let write_key k = write_eddsa (key_fpath k) k.priv

let delete_file fpath =
  (* check fpath just to be safe *)
  let () =
    let root = Fpath.v Cfg.key_dir in
    if not @@ Fpath.is_rooted ~root fpath then
      Fmt.failwith
        "delete_file failure: file `%a` is not contained in secmod directory"
        Fpath.pp fpath
  in
  Log.debug (fun m -> m "delete key file `%a`" Fpath.pp fpath);
  let+ () = Bos.OS.File.delete ~must_exist:true fpath |> unwrap_err_msg in
  ()

let get_key_dir_contents dir =
  let* dir = Fpath.of_string dir |> unwrap_err_msg in
  let* b = Bos.OS.Dir.create ~mode:0o700 dir |> unwrap_err_msg in
  if b then Log.info (fun m -> m "created directory `%a`" Fpath.pp dir);
  let+ l =
    Bos.OS.Dir.contents ~dotfiles:false ~rel:false dir |> unwrap_err_msg
  in
  List.map Fpath.normalize l

(* -- *)

let gen_key t1 t2 =
  let priv, pub = EddsaPrivateKey.generate () in
  Log.debug (fun m ->
      m "generated key (%a):@,`%s`" pp_filename (t1, t2)
        (EddsaPublicKey.to_b32 pub));
  { priv; pub; t1; t2 }

let sort_keys l = List.sort (fun a b -> TimeAbsolute.compare a.t2 b.t2) l

let split_in_periodes ~start ~end_ =
  assert (start < end_);
  (* no overlap on first periode *)
  let t1 = start in
  let t2 = TimeAbsolute.add start Cfg.duration in
  let acc = [ (t1, t2) ] in
  let start = t2 in
  let rec go acc start end_ =
    let t1 = TimeAbsolute.sub start Cfg.overlap_duration in
    let t2 = TimeAbsolute.add start Cfg.duration in
    if t2 > end_ then acc else go ((t1, t2) :: acc) t2 end_
  in
  go acc start end_

(* TODO do not exceed lookahead (probably more important...) *)
(* try to not generate keys with validity start in the past *)
let gen_additional_keys_until_lookahead ~now l =
  let start =
    match List.rev (sort_keys l) with
    | [] -> now
    | hd :: _ -> TimeAbsolute.sub hd.t2 Cfg.overlap_duration
  in
  let end_ = TimeAbsolute.add now Cfg.lookahead_sign in
  if TimeAbsolute.compare start end_ >= 0 then []
  else
    let periodes = split_in_periodes ~start ~end_ in
    let new_keys = List.map (fun (t1, t2) -> gen_key t1 t2) periodes in
    new_keys

(* TODO config *)
let sm_key_fpath =
  Result.get_ok
  @@
  let+ fpath = Fpath.of_string Cfg.sm_priv_key |> unwrap_err_msg in
  Fpath.normalize fpath

(* we load sm_key separately
   we don't accept non-key files in key_dir *)
let load_key fpath =
  match parse_filename fpath with
  | None -> Fmt.error "invalid file `%a`" Fpath.pp fpath
  | Some (t1, t2) ->
      let+ priv = read_key fpath in
      let pub = EddsaPrivateKey.pub_of_priv priv in
      { priv; pub; t1; t2 }

let load () =
  let* l = get_key_dir_contents Cfg.key_dir in
  let l = List.filter (fun fpath -> not @@ Fpath.equal fpath sm_key_fpath) l in
  let* keys = list_map load_key l in
  match keys with
  | [] -> Ok None
  | _l ->
      let* sm_key_priv = read_key sm_key_fpath in
      let sm_pub = EddsaPrivateKey.pub_of_priv sm_key_priv in
      let ht = Hashtbl.create 0xff in
      let () = List.iter (fun k -> Hashtbl.replace ht k.pub k) keys in
      Ok (Some { sm_key_priv; sm_pub; ht })

let init () =
  let* opt = load () in
  let* t =
    match opt with
    | Some t -> Ok t
    | None ->
        let sm_key_priv, sm_pub = EddsaPrivateKey.generate () in
        Log.debug (fun m ->
            m "generated secmod key: `%s`" (EddsaPublicKey.to_b32 sm_pub));
        let* () = write_eddsa sm_key_fpath sm_key_priv in
        let ht = Hashtbl.create 0xff in
        Ok { sm_key_priv; sm_pub; ht }
  in
  let now = TimeAbsolute.of_ptime (Ptime_clock.now ()) in
  let keys = List.of_seq @@ Hashtbl.to_seq_values t.ht in
  let new_keys = gen_additional_keys_until_lookahead ~now keys in
  List.iter (fun k -> Hashtbl.replace t.ht k.pub k) new_keys;
  let+ () = list_iter write_key new_keys in
  t

module Make () = struct
  let t =
    match init () with
    | Error e -> Fmt.failwith "secmod_eddsa initialization failure: %s." e
    | Ok t -> t

  let find pub =
    Hashtbl.find_opt t.ht pub |> Option.to_result ~none:"key not found"

  let add t1 t2 =
    let k = gen_key t1 t2 in
    Hashtbl.replace t.ht k.pub k;
    let+ () = write_key k in
    ()

  let delete pub =
    let* k = find pub in
    Hashtbl.remove t.ht k.pub;
    delete_file (key_fpath k)

  let _delete_outdated ~now =
    Hashtbl.to_seq_values t.ht
    |> List.of_seq
    |> List.filter (fun k -> TimeAbsolute.compare now k.t2 >= 0)
    |> List.map (fun k -> k.pub)
    |> list_iter delete

  (* ---- *)

  let sm_pub = t.sm_pub
  let sign_secmod s = EddsaSignature.sign ~key:t.sm_key_priv s

  let sign pub s =
    let+ k = find pub in
    let data = EddsaSignature.sign ~key:k.priv s in
    data

  (* delete and replace *)
  let revoke pub =
    let* k = find pub in
    let* () = delete pub in
    let* () = add k.t1 k.t2 in
    Ok ()

  let conv = fun { priv= _; pub; t1; t2 } -> (pub, (t1, t2))
  let keys () = Hashtbl.to_seq_values t.ht |> List.of_seq |> List.map conv
  let find_key pub = Hashtbl.find_opt t.ht pub |> Option.map conv
end

(* TODO
  - more checks
  - sign: check timestamps before signing
  - schedule tasks
  - !lock
*)