mte/tools/offline_impl.ml

open Syntax

let read_file fname = Bos.OS.File.read (Fpath.v fname) |> unwrap_err_msg

let write_file fname content =
  Bos.OS.File.write (Fpath.v fname) content |> unwrap_err_msg

let base_url = Uri.of_string "http://localhost:3434/"
let full_url path = Uri.with_path base_url path |> Uri.to_string

let download ~output =
  let open Bos in
  let uri = full_url "/management/keys/" in
  OS.Cmd.run Cmd.(v "curl" % "-s" % "-o" % output % "-X" % "GET" % uri)
  |> unwrap_err_msg

let upload ~input ~url =
  let open Bos in
  let uri = full_url url in
  OS.Cmd.run
    Cmd.(
      v "curl"
      % "-i"
      % "-X"
      % "POST"
      % "-H"
      % "Content-Type: application/json"
      % "--data"
      % ("@" ^ input)
      % uri)
  |> unwrap_err_msg

let setup ~output =
  let () = Mirage_crypto_rng_unix.use_default () in
  let priv, pub = Mirage_crypto_ec.Ed25519.generate () in
  Fmt.pr "generated master public key:@\n%s@."
    (Mirage_crypto_ec.Ed25519.pub_to_octets pub |> B32.encode);
  let priv_data = Mirage_crypto_ec.Ed25519.priv_to_octets priv in
  write_file output priv_data

let sign ~master_key ~input ~output =
  let open Crypto in
  let* input = read_file input in
  let* master_key = read_file master_key in
  let* master_key = EddsaPrivateKey.of_octets master_key in
  let master_pub = EddsaPrivateKey.pub_of_priv master_key in
  let* future_keys_response = Api.decode Api.FutureKeysResponse.jsont input in
  let* () =
    Offline_sig.verify_future_keys_response master_pub future_keys_response
  in
  let master_signatures =
    Offline_sig.make_master_signatures ~master_key future_keys_response
  in
  let* s = Api.encode Api.MasterSignatures.jsont master_signatures in
  let* () = write_file output s in
  Ok ()

let revoke_denom ~output ~master_key ~h_denom =
  let open Crypto in
  let* key = read_file master_key in
  let* key = EddsaPrivateKey.of_octets key in
  let* h_denom = B32.decode h_denom in
  let h_denom = Bin_type.DenominationHash.of_octets h_denom in
  let denom_revoke = Offline_sig.mk_denom_revoke ~key h_denom in
  let* s = Api.encode Api.DenomRevocationSignature.jsont denom_revoke in
  let* () = write_file output s in
  Ok ()

let revoke_signkey ~output ~master_key ~signkey =
  let open Crypto in
  let* key = read_file master_key in
  let* key = EddsaPrivateKey.of_octets key in
  let* signkey = EddsaPublicKey.of_b32 signkey in
  let v = Offline_sig.mk_signkey_revoke ~key signkey in
  let* s = Api.encode Api.SignkeyRevocationSignature.jsont v in
  let* () = write_file output s in
  Ok ()

let global_fees ~output ~master_key ~start_date ~end_date ~history_fee
    ~account_fee ~purse_fee ~history_expiration ~purse_account_limit
    ~purse_timeout =
  let open Crypto in
  let* key = read_file master_key in
  let* key = EddsaPrivateKey.of_octets key in
  let* purse_account_limit =
    match
      purse_account_limit >= 0
      && purse_account_limit <= Int32.to_int Int32.max_int
    with
    | false -> Error "invalid purse_account_limit value"
    | true -> Ok (Int32.of_int purse_account_limit)
  in
  let master_sig =
    let open Bin_sig.GlobalFees in
    (* TODO KYC *)
    let kyc_timeout = None in
    let kyc_fee = Amount.dummy_value in
    sign_f ~f:(EddsaSignature.sign ~key)
      {
        start_date;
        end_date;
        purse_timeout;
        kyc_timeout;
        history_expiration;
        history_fee;
        kyc_fee;
        account_fee;
        purse_fee;
        purse_account_limit;
      }
  in
  let global_fees =
    Api.GlobalFees.
      {
        start_date;
        end_date;
        purse_timeout;
        history_expiration;
        history_fee;
        account_fee;
        purse_fee;
        purse_account_limit;
        master_sig;
      }
  in
  let* s = Api.encode Api.GlobalFees.jsont global_fees in
  let* () = write_file output s in
  Ok ()