mte/test/crypto.ml

let encode = B32.encode
let decode s = B32.decode s |> Result.get_ok

let round_trip s =
  let s' = s |> encode |> decode in
  match s' = s with
  | false -> Fmt.failwith "b32 round trip failure: @\nin :`%S`@\nout:`%S`" s' s
  | true -> ()

let () =
  let s = String.init 0xff Char.chr in
  round_trip s;
  let s_l = List.init 0x0f (fun i -> String.init i Char.chr) in
  List.iter round_trip s_l; ()

(* test vectors from:
   https://git.gnunet.org/gnunet/gnunet/file/src/cli/util/crypto-test-vectors.json.html *)

let () =
  (* hash *)
  let input = "91JPRV3F5GG4EKJNDSJQ8" in
  let expected =
    "D0R24RZ1TPASVQ2NY56CT8AJDYZE9ZGDB0GVZ05E9D4YGZQW2RC5YFPQ0Q86EPW836DY7VYQTNFFJT3ZR2K508F4JVS5JNJKYN2MMFR"
  in
  let output =
    input |> decode |> Hash.H64.hash |> Hash.H64.to_octets |> encode
  in
  assert (output = expected);

  ()

let () =
  (* eddsa_key_derivation *)
  let pub = "3M9KK1WSNM1RTY5P72HKFA264V4B7MVHVJ08Y90CV06DYHV8XPP0" in
  let priv = "8QC2VNF8443S5KPNKMB4XMV58BTHWAKZ7SVW5WG3KRB37567XS90" in
  let pub' =
    let open Crypto in
    priv
    |> decode
    |> EddsaPrivateKey.of_octets
    |> Result.get_ok
    |> EddsaPrivateKey.pub_of_priv
    |> EddsaPublicKey.to_octets
    |> encode
  in
  assert (pub = pub');

  ()

let () =
  (* eddsa_signing *)
  let priv = "5077XJR9AMH4T97ACKFBVBJD0KFENHPV66B2Y1JBSKXBJKNZJ4E0" in
  let pub = "6E2F03JJ8AEDANTTZZ4SBZDFEEZSF8A9DVGTS6VFBCVZQYQ46RRG" in
  let data = "00000300000000000000" in
  let sig_ =
    "XCNJGJ96WPDH60YVMH6C74NGQSGJE3BC1TYMGX6BHY5DMZZZKTB373QTXJ507K5EBSG9YS2EYKHCX3ATRQ6P5MY9MXC4ZB1XSZ2X23G"
  in
  let open Crypto in
  let msg = decode data in
  let eddsa_priv =
    priv |> decode |> EddsaPrivateKey.of_octets |> Result.get_ok
  in
  let sig_' =
    EddsaSignature.sign ~key:eddsa_priv msg
    |> EddsaSignature.to_octets
    |> encode
  in
  assert (sig_ = sig_');
  let eddsa_pub = pub |> decode |> EddsaPublicKey.of_octets |> Result.get_ok in
  let eddsa_sig = sig_ |> decode |> EddsaSignature.of_octets |> Result.get_ok in
  let () =
    EddsaSignature.verify ~key:eddsa_pub eddsa_sig ~msg |> Result.get_ok
  in

  ()

let () =
  (* kdf *)
  let salt = "94KPT83PCNS7J83KC5P78Y8" in
  let ikm = "94KPT83MD1JJ0WV5CDS6AX10D5Q70XBM41NPAY90DNGQ8SBJD5GPR" in
  let ctx =
    "94KPT83141HPYVKMCNW78833D1TPWTSC41GPRWVF41NPWVVQDRG62WS04XMPWSKF4WG6JVH0EHM6A82J8S1G"
  in
  let out_len = 64 in
  let out =
    "GTMR4QT05Z9WF5HKVG0WK9RPXGHSMHJNW377G9GJXCA8B0FEKPF4D27RJMSJZYWSQNTBJ5EYVV7ZW18B48Z0JVJJ80RHB706Y96Q358"
  in

  let xts = salt |> decode in
  let ikm = ikm |> decode in
  let ctx = ctx |> decode in
  let okm = Crypto.Kdf.kdf ~xts ~ikm ~ctx ~len:out_len in
  let okm = okm |> encode in
  assert (okm = out);

  ()