mte/src/devices.ml

(* TODO KV store *)

type env = {
  caqti_switch: Caqti_miou.Switch.t;
  db_uri: Uri.t;
}

module Secmod_signkey = struct
  type t = {
    sm_key: Signkey.t;
    keys: Signkey.t list;
  }

  let v =
    let finally _key = () in
    Vif.Device.v ~name:"secmod_signkey" ~finally [] @@ fun (_env : env) ->
    let sm_key = Signkey.generate () in
    let keys = [ Signkey.generate () ] in
    { sm_key; keys }
end

module Secmod_denom = struct
  type t = {
    sm_key: Signkey.t;
    keys: Denomination.t list;
  }

  let v =
    let finally _key = () in
    Vif.Device.v ~name:"secmod_denom" ~finally [] @@ fun (_env : env) ->
    let sm_key = Signkey.generate () in
    let keys = List.map Denomination.make Config.Coin.all_coins in
    { sm_key; keys }
end

let secmod_signkey = Secmod_signkey.v
let secmod_denom = Secmod_denom.v

let db_connection : (env, Caqti_miou.connection) Vif.Device.device =
  let finally (module Conn : Caqti_miou.CONNECTION) = Conn.disconnect () in
  Vif.Device.v ~name:"db_connection" ~finally []
  @@ fun { caqti_switch; db_uri } ->
  match Caqti_miou_unix.connect ~sw:caqti_switch db_uri with
  | Error err ->
      Fmt.failwith "Database connection failure: %a." Caqti_error.pp err
  | Ok conn -> (
      match Pg.preflight conn with
      | Error err ->
          Fmt.failwith "Database preflight failure: %a." Caqti_error.pp err
      | Ok () -> conn)