mte/tools/offline.ml

(* TODO
   - clean up cmdliner
   - setup: need public key in config file
   - check sigs *)
(* doc: https://docs.taler.net/manpages/taler-exchange-offline.1.html *)
let version = "%%VERSION%%"
let base_url = Uri.of_string "http://localhost:3434/"

let download ~output =
  let open Bos in
  let uri = Uri.with_path base_url "/management/keys/" |> Uri.to_string in
  OS.Cmd.run Cmd.(v "curl" (* % "-s" *) % "-o" % output % "-X" % "GET" % uri)

let upload ~input =
  let open Bos in
  let uri = Uri.with_path base_url "/management/keys/" |> Uri.to_string in
  OS.Cmd.run
    Cmd.(
      v "curl"
      % "-i"
      % "-X"
      % "POST"
      % "-H"
      % "Content-Type: application/json"
      % "--data"
      % ("@" ^ input)
      % uri)

let setup ~output =
  let output = Fpath.v output in
  let () = Mirage_crypto_rng_unix.use_default () in
  let priv, pub = Mirage_crypto_ec.Ed25519.generate () in
  Fmt.pr "generated master public key:@\n%s@."
    (Mirage_crypto_ec.Ed25519.pub_to_octets pub |> B32.encode);
  let priv_data = Mirage_crypto_ec.Ed25519.priv_to_octets priv in
  Bos.OS.File.write output priv_data

let sign ~input ~output ~master_key =
  let open Syntax in
  let open Bos.OS in
  let open Crypto in
  let input = Fpath.v input in
  let output = Fpath.v output in
  let master_key = Fpath.v master_key in
  let* input = File.read input |> unwrap_err_msg in
  let* master_key = File.read master_key |> unwrap_err_msg in
  let master_key = EddsaPrivateKey.of_octets master_key in
  let* future_key_response = Api.decode Api.FutureKeysResponse.jsont input in
  let* () = Offline_bin.verify_future_key_response future_key_response in
  let master_signatures =
    Offline_bin.make_master_signatures ~master_key future_key_response
  in
  let* s = Api.encode Api.MasterSignatures.jsont master_signatures in
  let* () = File.write output s |> unwrap_err_msg in
  Ok ()

(* CLI *)

open Cmdliner
open Cmdliner.Term.Syntax

let setup_cmd =
  let doc = "Generate offline master keys" in
  let output =
    Arg.(
      value
      & opt filepath "data/eddsa_master_offline"
      & info [ "o"; "output" ] ~doc)
  in
  Cmd.make (Cmd.info "setup" ~version ~doc)
  @@
  let+ output = output in
  match setup ~output with
  | Error (`Msg err) ->
      Fmt.epr "Setup failure: %s@." err;
      exit 1
  | Ok () -> ()

let download_cmd =
  let doc = "GET /management/keys/" in
  let man =
    [ `S Manpage.s_description; `P "$(cmd) download /management/keys." ]
  in
  let output =
    Arg.(value & opt filepath "future_keys.json" & info [ "o"; "output" ] ~doc)
  in
  Cmd.make (Cmd.info "download" ~version ~doc ~man)
  @@
  let+ output = output in
  match download ~output with
  | Error (`Msg err) ->
      Fmt.epr "Download failure: %s@." err;
      exit 1
  | Ok () -> ()

let upload_cmd =
  let doc = "POST /management/keys/" in
  let man =
    [ `S Manpage.s_description; `P "$(cmd) upload /management/keys." ]
  in
  let input =
    Arg.(
      value & opt filepath "master_signatures.json" & info [ "i"; "input" ] ~doc)
  in
  Cmd.make (Cmd.info "upload" ~version ~doc ~man)
  @@
  let+ input = input in
  match upload ~input with
  | Error (`Msg err) ->
      Fmt.epr "Upload failure: %s@." err;
      exit 1
  | Ok () -> ()

let sign_cmd =
  let doc = "Sign FutureKeysResponse." in
  let input =
    Arg.(value & opt filepath "future_keys.json" & info [ "i"; "input" ] ~doc)
  in
  let output =
    Arg.(
      value
      & opt filepath "master_signatures.json"
      & info [ "o"; "output" ] ~doc)
  in
  let master_key =
    let doc = "Master offline Eddsa private key file." in
    Arg.(
      value
      & opt filepath "data/eddsa_master_offline"
      & info [ "master-key" ] ~doc)
  in
  Cmd.make (Cmd.info "sign" ~version ~doc)
  @@
  let+ input = input and+ output = output and+ master_key = master_key in
  match sign ~input ~output ~master_key with
  | Error (*`Msg*) err ->
      Fmt.epr "Signature failure: %s@." err;
      exit 1
  | Ok () -> ()

let cli =
  let info =
    let doc = "MTE Offline CLI tool" in
    Cmd.info "mte-offline" ~version ~doc
  in
  Cmd.group info [ setup_cmd; download_cmd; sign_cmd; upload_cmd ]

let main () = Cmd.eval cli
let () = exit (main ())